The Flash Art of War

package com.jessefreeman.utils {
       
        import flash.display.DisplayObject;
        import flash.display.Loader;
        import flash.display.MovieClip;
        import flash.events.*;
        import flash.events.Event;
        import flash.events.EventDispatcher;
        import flash.events.IEventDispatcher;
        import flash.net.URLLoader;
        import flash.net.URLRequest;
        import flash.system.ApplicationDomain;
        import flash.system.LoaderContext;
        import flash.utils.Proxy;
        import flash.utils.getDefinitionByName;
        public class RuntimeAssetExplorerUtility extends Proxy implements IEventDispatcher {
               
                public static const INIT:String = “init”;
                private static var __instance:RuntimeAssetExplorerUtility;
                private var eventDispatcher:EventDispatcher;
                private var data:XML;
                private var urlLoader:URLLoader;
               
                private var _assets_list:Array;
               
                /**
                 * Use RuntimeAssetExplorerUtility.instance to access method on the utility.
                 * @return instance: Reference to the class
                 */
                public static function get instance ():RuntimeAssetExplorerUtility{
                        if(RuntimeAssetExplorerUtility.__instance == null) {
                                RuntimeAssetExplorerUtility.__instance = new RuntimeAssetExplorerUtility(new SingletonEnforcer());
                        }
                        return RuntimeAssetExplorerUtility.__instance;
                }
               
                /**
                 * A singleton Utility used to load external swfs and pull Linked Library Elements out of it. External swf’s library assets must
                 * be linked to real class files for them to get compiled into the swf and become accessible. Using Flash’s auto class creator
                 * when the class does not exist will not work.
                 */
                public function RuntimeAssetExplorerUtility(enforcer:SingletonEnforcer) {
                        eventDispatcher = new EventDispatcher();
                }
               
                /**
                 * Loads and external library swf
                 * @param url: String path to external swf
                 */
                public function load_library(url:String):void{
                        var path:URLRequest = new URLRequest(url);
                        var context:LoaderContext = new LoaderContext(false, ApplicationDomain.currentDomain);
                        var loader:Loader = new Loader();
                        loader.contentLoaderInfo.addEventListener(Event.COMPLETE,library_load_complete);
                        loader.load(path,context);
                }
               
                /**
                 * Fires off an INIT event to let listeners know the library is availible for use.
                 */
                private function library_load_complete(event:Event):void {                 
                        var library_assets:* = event.target.content;
               
                        dispatchEvent(new Event(RuntimeAssetExplorerUtility.INIT, true, true));
                }
               
                /**
                 * This returns a libary assets and when it is created, passes in the config object into the class’s construtor.
                 * @param class_name: Full class path name to library asset - "com.jessefreeman.ui.Button"
                 * @param config: Object with configuration data used by the constructor of the class being retrieved.
                 * @return: initialized MovieClip instance of class. Asset will still need to be added to the display tree to be seen.
                 * @example
                 *
                 * var header_config:Object = new Object()
                 *            header_config.x = 0;
                 *            header_config.y = 0;
                 *           
                 *      addChild(RuntimeAssetExplorerUtility.instance.add_asset_to_stage(
"com.photogallery.v2.views.skins.assets.Header",header_config))
                 */
                public function get_library_asset(class_name:String, config:Object):* {
                       
                        var AssetClass:Class = getDefinitionByName(class_name) as Class;
                       
                        if(AssetClass) {
                                var mc:* = new AssetClass(config);
                                return mc;
                        }else{
                                return null;   
                        }

                }
               
                /** Following allows Event dipatch and listen support to Singleton **/

                public function addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, weakRef:Boolean = false):void {
                        eventDispatcher.addEventListener(type, listener, useCapture, priority, weakRef);
                }
               
                public function dispatchEvent(event:Event):Boolean {
                        return eventDispatcher.dispatchEvent(event);
                }
               
                public function hasEventListener(type:String):Boolean {
                        return eventDispatcher.hasEventListener(type);
                }
               
                public function removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void {
                        eventDispatcher.removeEventListener(type, listener, useCapture);
                }
               
                public function willTrigger(type:String):Boolean {
                        return eventDispatcher.willTrigger(type);
                }

        }
}

class SingletonEnforcer {}